HSP Tips 7

　インターネットブラウザを起動して、検索エンジンGoogle＆Yahoo! Japanでキーワード検索を行ってみーる。URLアドレスに検索するためのキーワードを引っ付けてやればOK。ちなみに、Yahoo!はいちおうキーワードをUTF-8でエンコードしてやる必要がありますが、めんどいので「ei=Shift_JIS」パラメータを付けて回避してます（参考）。

※ 検索エンジンが仕様変更を行った場合、下のサンプルコードがうまく利用できなくなる可能性があります。

//	検索エンジンでキーワード検索 (by Kpan)

	keyword = "Let's HSP!"
	input keyword, 150

	button "ぐーぐる", *search_google
	button "やふー", *search_yahoo
	stop

*search_google
	exec "http://www.google.co.jp/search?q="+keyword+"", 16
	stop

*search_yahoo
	exec "http://search.yahoo.co.jp/search?ei=Shift_JIS&p="+keyword+"", 16
	stop

　Windows 98以降（Windows 95の場合はIE4.0以降）には、「Webdings」と「Wingdings」というフォントがシステムに用意されてます。これは普通の文字フォントと違って、絵文字フォントと呼ばれるものです。これをオブジェクトなんかに利用すれば、ちょっとしたイメージボタン風。（＾ー＾）b

　オブジェクト上に指定できる文字は半角の英数字や記号のみで、半角カタカナや特殊な記号など（文字コード｢0128｣以降）は表示不可能？。HSP3の場合はstrf関数とmes命令と組み合わせですべて表示可能。どのような絵文字があるかは、それぞれのフォント名で検索すれば、絵文字の一覧表を掲載したページがザックザクとヒットします。

//	絵文字フォントの利用 (HSP3/HSP2)
//	by Kpan

	objmode 2

	objsize 400, 50

	font "webdings", 25
	button "A N J z + - \\ \" %", *dummy

;	！strf関数を利用しているため、以下の1行はHSP3のみ
	mes ""+strf("%c", 255)+" "+strf("%c", 173)+""

	font "wingdings", 20
	button "6 J ( [ v % M * $", *dummy

*dummy

//	絵文字フォントの表示 (HSP3)
//	by Kpan

	sdim data
	font "Wingdings", 30, 16

	i = 32
	repeat 12
		repeat 20
			poke data, cnt, strf("%c", i)
			i++
		loop

		color , , rnd(255)
		mes data

		wait 50
	loop

　Windowsの細かい部分部分の配色。この色は、Windowsの画面のプロパティにある「デザイン」タブ→[詳細設定]で変更できます。HSP3から登場したsyscolor命令を利用すると、設定されている色を取得できます。(→ システムカラー確認ツールをこしらえてみるー)

　システムカラーの一覧をババッと表示、マウスポインタ位置でRGBカラー値をタイトルバーに、なスクリプトコード。インデックス番号は0〜30で、25は欠番です。

//	HSP3向け システムカラー一覧表示 (by Kpan)
//	！HSPスクリプトエディタの[HSP]→[HSP拡張マクロを使用する]を要有効

;	なくてもいいけど、背景にHSP付属の画像を拝借して見やすいよーに
	picload dirinfo(1) + "/sample/demo/sky_bg.jpg", 1


;	0〜9のシステムカラー
	i = 0
	repeat 10
;		カラーを取得し、boxf命令で四角塗りつぶし
		syscolor i : boxf 60 + cnt * 50, 50, 100 + cnt * 50, 90
;		インデックス番号を黄色で		
		pos 60 + cnt * 50, 50 : color 255, 255, 0 : mes ""+i
		i++
	loop

;	10〜19のシステムカラー
	i = 10
	repeat 10
		syscolor i : boxf 60 + cnt * 50, 105, 100 + cnt * 50, 145
		pos 60 + cnt * 50, 105 : color 255, 255, 0 : mes ""+i
		i++
	loop

;	20〜29のシステムカラー
	i = 20
	repeat 10
		syscolor i : boxf 60 + cnt * 50, 160, 100 + cnt * 50, 200
		pos 60 + cnt * 50, 160 : color 255, 255, 0 : mes ""+i
		i++
	loop

;	30のシステムカラー
	i = 30
	repeat 1
		syscolor i : boxf 60 + cnt * 50, 215, 100 + cnt * 50, 255
		pos 60 + cnt * 50, 215 : color 255, 255, 0 : mes ""+i
		i++
	loop


;	マウスポインタループ
	repeat
		wait 20
		pget mousex, mousey
		title "R:"+ginfo(16)+" / G:"+ginfo(17)+" / B:"+ginfo(18)
	loop